今日はAKI-80、AKI-ROMライタともに完成したということで、TAIKIさんに私の部屋に来ていただきました（遠いところをご苦労様です）。
とりあえずマイコンを使って工作をする環境は整ったわけですから、とりあえず動作確認もかねて簡単なものを作っていただき感触をつかんでいただこうととになりました。
最初の課題はずばり、「ＬＥＤ（発光ダイオード）を点滅させる」というものです。
本来ならハードの設計が先にあることが多いのですが、いきなりということもあるので私の方でプログラムを用意して（といってもKOKEさんに手伝っていただきながらその場で適当に作りました）、それを説明しながらTAIKI氏にハードを組み立てて頂くという手順を選びました。今回はLSIC-80のアセンブラとリンカを利用してＲＯＭ化用のＨＥＸファイルを生成します。
細かい説明は今後行うとして、今回は大雑把に流れだけ理解して下さい。
; ---------------------------------------------------------------------
; TAIKI氏に捧げるLED点灯プログラム
; ---------------------------------------------------------------------
; ----- ポート定義 (1)
PIOA equ 01ch
PIOAC equ 01dh
; ----- コードセグメント開始 (2)
cseg
start:
; ----- スタックポインタ初期化 (3)
ld sp,0
; ----- PIO初期化 (4)
ld a,0cfh
out (PIOAC),a ; PIOAをビットモードに
ld a,000h
out (PIOAC),a ; すべて出力
ld a,007h
out (PIOAC),a ; 割り込みは使用しない
; ----- 点滅 (5)
loop:
ld a,0aah
out (PIOA),a ; 交互に点灯
call Wait ; ウェイトルーチンを呼び出し (6)
ld a,055h
out (PIOA),a ; さっきの反転で点灯
call Wait ; １秒程度待つ
jp loop ; 無限に繰り返す
; ----- ウェイト (7)
Wait:
ld de,1000 ; 1ms待ちを1000回行う
Wait_loop:
call Wait1ms ; 1ms待つ
dec de ; デクリメント
ld a,d
or e
jr nz,Wait_loop ; ループ終了条件比較
ret ; リターン
; ----- 1msec待ち
Wait1ms:
ld bc,375 ; 1msec待つためのループ数 (8)
Wait1msLoop: dec bc
ld a,c
or b
jr nz,Wait1msLoop
ret
end
大変大雑把にですが、プログラムの説明をします
ここでは equ という擬似命令を使って定数を宣言しています。Ｃ言語の #define と同じと考えていただければ分かりやすいでしょう。で、何を定義しているかです。
今回はLEDを点滅させるためにZ80-PIOというパラレル制御のためのＬＳＩを操作します。ＣＰＵにはＩ／Ｏポートという外部機器を制御するためのポートが備わっていて、それぞれのポートにいろいろな機能のＬＳＩを繋ぐことが出来ます。AKI-80の場合はTMPZ84C015BFというワンチップマイコンが載っていますのでこのZ80-PIOが内蔵されており 0x1c からのポートがこのPIOの制御ポートとして割り当てられています。
マイコン用のプログラムではコード（プログラム）、初期化されるデータ、初期化されないデータなどに応じてＲＯＭやＲＡＭに配置してやらなければなりません。実際のアドレスはリンク時に指定するのですが、プログラムの中ではとりあえず何処がどういう部分か指定してやります。 cseg 擬似命令は「これ以降はコードセグメントというコードの入ったブロックだよ」とアセンブラに指示してやるためのものです。
アセンブラをやる上で常に無視できないのがスタックです。スタックとはどういう物かというと結局データの格納場所で格納したデータを格納した順とは逆順で取り出せる機構です。データの一時待避やサブルーチンコール時の戻り場所の保存、Ｃ言語などでは自動変数の割り当てにも利用されます。そしてその機構を一人で背負って立つのが sp(スタックポインタ）レジスタなのです。
spはデータの格納の必要が生じるとそのサイズ分値を減算し、そのアドレスにデータを書き込みます(push)。逆にデータを取り出す時は、データを取り出した後、そのザイズ分spを加算します(pop)。つまりスタックはメモリの高位アドレスから低位アドレスに向かってデータを格納していきます。そのため通常はＲＡＭ領域の最後にspを設定します。AKI-80の場合は 0000〜7fff がＲＯＭ、8000〜ffff までがＲＯＭですから、spはffffの次のアドレスである 0000 に初期設定します。
PIOとはパラレルＩ／Ｏのことでデータを8bitの入出力端子を持ったデバイスです。今回はPIOのＡポートの端子にLEDを取り付けて、各ビット毎に１出力で点灯させ、０出力で消灯させます。そのため、PIOのＡポートをそれに適したモードに初期設定せねばなりません。PIOのＡポートを制御するＩＯポートは２つあり、上記プログラムではPIOAとPIOACで定義しています。ここでPIOAは８本の端子と直接データを入出力するものであり、PIOAC がモード設定などを行うものです。
とりあえず詳しい説明は今後ということにしますが、ここで行っている処理は、PIOをビットモードという単純な入出力を行うモードにしてすべてのピンを出力に設定しています。よって今後 PIOA に書き込んだ値はそのまま２進数として各端子に０のときはＬレベル（０Ｖに近い電圧）、１のときはＨレベル（５Ｖに近い電圧）が出力されます。
いよいよ、点滅させるルーチンです。今回は各ビットを交互に点灯させようということで 10101010 (AA) と 01010101 (55)を間にウェイトを入れながら繰り返し出力することにしました。PIOのモード設定は終わっていますので後は PIOA に AA と 55 を交互に出力するだけです。
Z80と言えども馬鹿にしてはいけません。4MHzでもPC-8801やＭＳＸなどでガンガンゲームが楽しめるわけで、AKI-80の場合 10MHzで動いてるわけですからその速度はたいした物です。大雑把に１命令に数μ秒と見積もっても単純ループさせると１秒間に１０万回程度点滅を繰り返します。秒間３０コマのＴＶにしっかり騙されてる人間がこんなものを見たって点滅には見えません（これを利用してダイナミック点灯という技がありますが）。というわけでウェイトを入れます。Ｃ言語などですと関数呼び出しに当たるのがこの call 命令です。どういう動作をするかと言うと、現在実行中の番地(PC)をスタックに積み、オペランドで指定されたアドレスにジャンプします。サブルーチンから帰るときは ret というＣ言語の return に相当する命令を利用して帰ってきます。 ret はスタックからアドレスを取り出し、PC(プログラムカウンタ)にセットする働きがあります。
PC <- PC + 3 （自分の命令サイズ分PCを進める） SP <- SP - 2 （PCのサイズ分スタックポインタを移動） (SP) <- PC (スタックにPCを保存） PC <- nn （指定されたアドレスにジャンプ）
PC <- (SP) （スタックから戻るアドレスを取り出す） SP <- SP + 2 （取り出したサイズ分スタックポインタを戻す）
「1msecってどうやって決めるの？」TAIKI氏から鋭い突っ込みを受けました。
この辺がマイコンのマイコンたるところで割り込みや他のタスクが走っている普通のＰＣではあまり見かけないテクニックですね。
当たり前の話ですが、ＣＰＵが命令を実行する時間というのは初めからわかっていて、どの命令にステート利用するかはわかっていますからクロックから計算可能なわけです。
Wait1msLoop: dec bc --- ６ステート ld a,c --- ４ステート or b --- ４ステート jr nz,Wait1msLoop --- １２ステート（ジャンプ時）
上記のようにループ１回につき２６ステートです。AKI-80を 9.8304 MHzで動かした場合１ステートは１クロックですので 9,830,400 ÷ ２６ ≒ ３７８回ループすればいい計算になります。上記プログラムではこれからさらに関数の呼び出しとリターンの時間を差し引いて３７５回のループを行っています。
いやー、相変わらず実に大雑把ですね。今回の説明だけでは何が何やらという人も多いと思います。ぼちぼち補完していきますんでご容赦下さい。m(_ _)m